// CC0: Reflective 4D Julia
// Late to the party experimenting with 4D julias.
// Distance function from IQ's Quaternion 1 : https://www.shadertoy.com/view/MsfGRr

#define TIME            iTime
#define RESOLUTION      iResolution

#define PI              3.141592654
#define TAU             (2.0*PI)

#define TOLERANCE       0.0001
#define MAX_RAY_LENGTH  24.0
#define MAX_RAY_MARCHES 100
#define MAX_REF_MARCHES 30
#define MAX_SHADOW_MARCHES 20
#define NORM_OFF        0.001
#define ROT(a)          mat2(cos(a), sin(a), -sin(a), cos(a))

// License: WTFPL, author: sam hocevar, found: https://stackoverflow.com/a/17897228/418488
const vec4 hsv2rgb_K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
vec3 hsv2rgb(vec3 c) {
  vec3 p = abs(fract(c.xxx + hsv2rgb_K.xyz) * 6.0 - hsv2rgb_K.www);
  return c.z * mix(hsv2rgb_K.xxx, clamp(p - hsv2rgb_K.xxx, 0.0, 1.0), c.y);
}
// License: WTFPL, author: sam hocevar, found: https://stackoverflow.com/a/17897228/418488
//  Macro version of above to enable compile-time constants
#define HSV2RGB(c)  (c.z * mix(hsv2rgb_K.xxx, clamp(abs(fract(c.xxx + hsv2rgb_K.xyz) * 6.0 - hsv2rgb_K.www) - hsv2rgb_K.xxx, 0.0, 1.0), c.y))

const float hoff      = 0.0;
const vec3 skyCol     = HSV2RGB(vec3(hoff+0.57, 0.70, 0.25));
const vec3 sunCol1    = HSV2RGB(vec3(hoff+0.60, 0.50, 0.5));
const vec3 sunCol2    = HSV2RGB(vec3(hoff+0.05, 0.75, 25.0));
const vec3 skylineCol = HSV2RGB(vec3(hoff+0.35, 0.85, 0.0025));
const vec3 diffCol    = HSV2RGB(vec3(hoff+0.60, 0.75, 0.2));
const vec3 sunDir1    = normalize(vec3(3., 3.0, -7.0));

const mat2 rot0 = ROT(0.0);

float g_zoff = 0.0;
mat2 g_rot0 = rot0;
mat2 g_rot1 = rot0;
mat2 g_rot2 = rot0;

// License: Unknown, author: nmz (twitter: @stormoid), found: https://www.shadertoy.com/view/NdfyRM
vec3 sRGB(vec3 t) {
  return mix(1.055*pow(t, vec3(1./2.4)) - 0.055, 12.92*t, step(t, vec3(0.0031308)));
}

// License: Unknown, author: Matt Taylor (https://github.com/64), found: https://64.github.io/tonemapping/
vec3 aces_approx(vec3 v) {
  v = max(v, 0.0);
  v *= 0.6f;
  float a = 2.51f;
  float b = 0.03f;
  float c = 2.43f;
  float d = 0.59f;
  float e = 0.14f;
  return clamp((v*(a*v+b))/(v*(c*v+d)+e), 0.0f, 1.0f);
}

// License: MIT, author: Inigo Quilez, found: https://iquilezles.org/articles/distfunctions/
float rayPlane(vec3 ro, vec3 rd, vec4 p) {
  return -(dot(ro,p.xyz)+p.w)/dot(rd,p.xyz);
}

// License: MIT, author: Inigo Quilez, found: https://iquilezles.org/www/articles/distfunctions2d/distfunctions2d.htm
float box(vec2 p, vec2 b) {
  vec2 d = abs(p)-b;
  return length(max(d,0.0)) + min(max(d.x,d.y),0.0);
}

vec3 render0(vec3 ro, vec3 rd) {
  vec3 col = vec3(0.0);
  float sd = max(dot(sunDir1, rd), 0.0);
  float sf = 1.0001-sd;

  col += skylineCol/abs(abs(rd.y));
  col += 0.5*skyCol*pow((1.0-abs(rd.y)), 8.0);
  col += sunCol1*pow(sd, 100.0);
  col += sunCol2*pow(sd, 800.0);
  float tp1  = rayPlane(ro, rd, vec4(vec3(0.0, -1.0, 0.0), 6.0));

  if (tp1 > 0.0) {
    vec3 pos  = ro + tp1*rd;
    vec2 pp = pos.xz;
    float db = box(pp, vec2(5.0, 9.0))-3.0;

    col += vec3(4.0)*skyCol*rd.y*rd.y*smoothstep(0.25, 0.0, db);
    col += vec3(0.8)*skyCol*exp(-0.5*max(db, 0.0));
    col += 0.25*sqrt(skyCol)*max(-db, 0.0);
  }

  return clamp(col, 0.0, 10.0);
}

float dot2(vec4 p) {
  return dot(p, p);
}

vec4 q2(vec4 a) {
    return vec4(a.x*a.x - dot(a.yzw,a.yzw), 2.0*a.x*(a.yzw));
}

// From IQ's - Quaternion 1 : https://www.shadertoy.com/view/MsfGRr
float julia(vec3 p, vec4 c) {
  vec4 z = vec4(p, g_zoff);
  z.wz *= g_rot0;
  z.wx *= g_rot1;
  z.wy *= g_rot2;
  float md2 = 1.0;
  float mz2 = dot2(z);

  for(int i=0; i<8; ++i) {
    md2 *= 4.0*mz2;
    z = q2(z) + c;

    mz2 = dot2(z);
    if(mz2>40.0) break;
  }

  return 0.25*sqrt(mz2/md2)*log(mz2);  // d = 0.5·|z|·log|z|/|z'|
}


float df(vec3 p) {
  const vec4 c = 0.45*cos( vec4(0.5,3.9,1.4,1.1) + 0.9*vec4(1.2,1.7,1.3,2.5) ) - vec4(0.3,0.0,0.0,0.0);
  float d0 = p.x+3.0;
  const float z = 3.0;
  float d1 = julia(p/z, c)*z;
  float d= d0;
  d = min(d, d1);
  return d;
}

vec3 normal(vec3 pos) {
  vec2  eps = vec2(NORM_OFF,0.0);
  vec3 nor;
  nor.x = df(pos+eps.xyy) - df(pos-eps.xyy);
  nor.y = df(pos+eps.yxy) - df(pos-eps.yxy);
  nor.z = df(pos+eps.yyx) - df(pos-eps.yyx);
  return normalize(nor);
}

float rayMarch(vec3 ro, vec3 rd) {
  float t = 0.0;
  const float tol = TOLERANCE;
  vec2 dti = vec2(1e10,0.0);
  int i = 0;
  for (i = 0; i < MAX_RAY_MARCHES; ++i) {
    float d = df(ro + rd*t);
    if (d<dti.x) { dti=vec2(d,t); }
    if (d < TOLERANCE || t > MAX_RAY_LENGTH) {
      break;
    }
    t += d;
  }
  if(i==MAX_RAY_MARCHES) { t=dti.y; };
  return t;
}

float shadowMarch(in vec3 ps, in vec3 ld, in float mint, in float k) {
  float res = 1.0;
  float t = mint*2.0;
  for (int i=0; i<MAX_SHADOW_MARCHES; ++i) {
    vec3 p = ps + ld*t;
    float d = df(p);
    res = min(res, k*d/t);
    if (res < TOLERANCE) break;

    t += max(d, mint);
  }
  return clamp(res, 0.0, 1.0);
}

vec3 render1(vec3 ro, vec3 rd) {
  float t = rayMarch(ro, rd);
  vec3 col = vec3(0.0);

  vec3 p = ro+rd*t;
  vec3 n = normal(p);
  vec3 r = reflect(rd, n);
  float sd = shadowMarch(p, sunDir1, 0.025, 8.0);
  float rf = shadowMarch(p, r, 0.025, 4.0);

  float dif = max(dot(sunDir1, n), 0.0);
  dif *= dif;
  dif *= dif;
  vec3 rcol = render0(p, r);
  if (t < MAX_RAY_LENGTH) {
    col = diffCol;
    col *= mix(0.2, 1.0, dif);
    col *= mix(0.2, 1.0, abs(sd));
    col += rcol*rf;
  }

  return col;
}

vec3 effect(vec2 p) {
  const vec3 ro = vec3(5.0, 0.5, 1.2);
  const vec3 la = vec3(0.0, 0.0, 0.0);
  const vec3 up = normalize(vec3(0.0, 1.0, 0.0));

  const vec3 ww = normalize(la - ro);
  const vec3 uu = normalize(cross(up, ww ));
  const vec3 vv = (cross(ww,uu));
  const float fov = tan(TAU/6.);

  g_zoff = 0.25*sin(0.06*TIME);
  g_rot0 = ROT(0.1*TIME);
  g_rot1 = ROT(0.21*TIME);
  g_rot2 = ROT(0.32*TIME);

  vec3 rd = normalize(-p.x*uu + p.y*vv + fov*ww);
  vec3 col = render1(ro, rd);
  return col;
}

void mainImage(out vec4 fragColor, in vec2 fragCoord) {
  vec2 q = fragCoord/RESOLUTION.xy;
  vec2 p = -1. + 2. * q;
  vec2 pp = p;
  p.x *= RESOLUTION.x/RESOLUTION.y;
  vec3 col = vec3(0.0);
  col = effect(p);
//  col *= smoothstep(1.75, 1.0-0.5, length(pp));
  col = aces_approx(col);
  col = sRGB(col);
  fragColor = vec4(col, 1.0);
}